mass_balance__soil.F90

Go to the documentation of this file.

module mass_balance__soil
 
  use iso_c_binding, only              : c_float, c_double
  use constants_and_conversions, only  : near_zero
  implicit none
 
  private
 
  public :: calculate_soil_mass_balance
 
contains
 
   elemental subroutine calculate_soil_mass_balance( net_infiltration,      &
                                                     soil_storage,          &
                                                     actual_et_soil,        &
                                                     runoff,                &
                                                     delta_soil_storage,    &
                                                     reference_et0,         &
                                                     soil_storage_max,      &
                                                     infiltration )
 
    real (c_float), intent(inout)      :: net_infiltration
    real (c_double), intent(inout)     :: soil_storage
    real (c_double), intent(inout)     :: actual_et_soil
    real (c_float), intent(inout)      :: runoff
    real (c_float), intent(inout)      :: delta_soil_storage
    real (c_double), intent(in)        :: reference_et0
    real (c_float), intent(in)         :: soil_storage_max
    real (c_float), intent(in)         :: infiltration
 
    ! [ LOCALS ]
    real (c_double) :: new_soil_storage
 
    ! all of these entities have been previously corrected for pervious fraction
    new_soil_storage = soil_storage + infiltration - actual_et_soil
 
    ! open water cell
    if ( soil_storage_max < near_zero ) then
 
      actual_et_soil = min( reference_et0, real(infiltration, c_double) )
      net_infiltration = 0.0_c_float
      ! **** infiltration term includes the previously calculated runoff; add this back in
      !      before adjusting the runoff value
      runoff = real(max( 0.0_c_double, real(infiltration, c_double) + runoff - actual_et_soil ), c_float)
      soil_storage = 0.0_c_float
      delta_soil_storage = 0.0_c_float
 
    ! new soil storage value exceeds soil_storage_max; net infiltration event
    elseif ( new_soil_storage > soil_storage_max ) then
 
      net_infiltration    = real(new_soil_storage - soil_storage_max, c_float)
 
      ! should represent a positive change in storage
      delta_soil_storage  = real(soil_storage_max - soil_storage, c_float)
!      actual_et_soil      = max( 0.0_c_float, soil_storage + infiltration - net_infiltration )
      soil_storage        = soil_storage_max
 
    else
 
      ! could be positive or negative
      delta_soil_storage  = real(new_soil_storage - soil_storage, c_float)
      soil_storage = new_soil_storage
      net_infiltration = 0.0_c_float
 
    endif
 
  end subroutine calculate_soil_mass_balance
 
end module mass_balance__soil