et__jensen_haise.F90

Go to the documentation of this file.

!> @file
!>  Contains a single module, et_jensen_haise, which
!>  calculates potential evapotranspiration by means of the Jensen-Haise (1963) method.
 
 
!>  Calculates potential evapotranspiration by means of the
!>  Jensen-Haise (1963) method.
module et__jensen_haise
!!****h* SWB/et_jensen_haise
! NAME
!   et_jensen_haise.f95 - Evapotranspiration calculation using the
!   Jensen-Haise method.
!
! SYNOPSIS
!   This module calculates evapotranspiration using the Jensen-Haise
!   method.
!
! NOTES
!   Original method is documented in:
!
!   Jensen, M.E., H.R. Haise. 1963. Estimating evapotranspiration from solar
!   radiation. Journal of Irrigation and Drainage Engineering 89(IR4):15-41.
!
!!***
 
  use iso_c_binding,               only : c_short, c_int, c_float, c_double
  use solar_calculations,          only : estimate_percent_of_possible_sunshine__psun,   &
                                          relative_earth_sun_distance__d_r,              &
                                          extraterrestrial_radiation__ra,                &
                                          solar_declination_simple__delta,               &
                                          sunrise_sunset_angle__omega_s,                 &
                                          solar_radiation__rs
  use meteorological_calculations, only : equivalent_evaporation
  use constants_and_conversions,   only : f_to_k, rfreezing, mm_per_in
 
  implicit none
 
  private
 
  public :: et_jh_calculate
 
contains
 
elemental function et_jh_calculate( iDayOfYear, iNumDaysInYear, fLatitude, fTMin, fTMax,    &
                                    fAs, fBs, fSunPct )                      result(fReferenceET0)
 
  integer (c_int), intent(in)          :: idayofyear
  integer (c_int), intent(in)          :: inumdaysinyear
  real (c_float), intent(in)           :: flatitude
  real (c_float), intent(in)           :: ftmin
  real (c_float), intent(in)           :: ftmax
  real (c_float), intent(in), optional :: fas
  real (c_float), intent(in), optional :: fbs
  real (c_float), intent(in), optional :: fsunpct
  real (c_double)                      :: freferenceet0
 
  ! [ LOCALS ]
  real (c_double) :: dra
  real (c_double) :: ddelta
  real (c_double) :: domega_s
  real (c_double) :: dd_r
  real (c_double) :: drs
  real (c_float)  :: ftavg
 
  real (c_double) :: das_l
  real (c_double) :: dbs_l
  real (c_double) :: dsunpct_l
 
  if (present( fas ) ) then
    das_l = fas
  else
    das_l = 0.25_c_double
  endif
 
  if (present( fbs ) ) then
    dbs_l = fbs
  else
    dbs_l = 0.5_c_double
  endif
 
  if (present( fsunpct ) ) then
    dsunpct_l = fsunpct
  else
    dsunpct_l = estimate_percent_of_possible_sunshine__psun(ftmax=f_to_k( ftmax ), ftmin=f_to_k( ftmin ) )
  endif
 
 
  ftavg = ( ftmin + ftmax ) / 2_c_float
 
!  fD_r = 1.0_c_float + 0.033_c_float * cos( TWOPI * iDayOfYear / iNumDaysInYear )
 
  dd_r = relative_earth_sun_distance__d_r( idayofyear=idayofyear, inumdaysinyear=inumdaysinyear )
 
!  fDelta = 0.4093_c_float * sin( (TWOPI * iDayOfYear / iNumDaysInYear ) - 1.405_c_float )
 
  ddelta = solar_declination_simple__delta( idayofyear=idayofyear, inumdaysinyear=inumdaysinyear )
 
!  fOmega_s = acos( -tan(fLatitude) * tan(fDelta) )
 
  domega_s = sunrise_sunset_angle__omega_s( real( flatitude, c_double), ddelta )
 
!  dSo = 2.44722_c_float * 15.392_c_float * dD_r * (     dOmega_s  * sin(dLatitude) * sin(dDelta) + &
!                                                  sin(dOmega_s) * cos(dLatitude) * cos(dDelta) )
 
  dra =  extraterrestrial_radiation__ra(dlatitude=real( flatitude, c_double),    &
                                                        ddelta=ddelta,                &
                                                        domega_s=domega_s,            &
                                                        ddsubr=dd_r )
 
!  dSn = dSo * ( 1.0_c_float - fAlbedo_l ) * ( fAs_l + fBs_l * fSunPct_l / 100.0_c_float )
 
  drs = solar_radiation__rs(dra=dra, das=das_l, dbs=dbs_l, fpctsun=dsunpct_l )
 
  if ( ftavg <= rfreezing ) then
    freferenceet0 = 0.0_c_float
  else
    ! 'equivalent_evaporation' yields the depth of water that could be evaporated for the
    ! given solar radiation in mm
    freferenceet0 = ( 0.014_c_float * ftavg - 0.37_c_float ) * equivalent_evaporation( drs ) / mm_per_in
!    fReferenceET0 = UNIT_CONV * ( 0.025_c_float * fTAvg + 0.078_c_float ) * fSn
  end if
 
!> @todo Check these equations against original paper.
 
!! original paper gives ET0 as:
 
!! Etp = ( 0.014 * Tavg - 0.37 ) * Rs
!
! where Rs is the solar radiation in inches per day
 
end function et_jh_calculate
 
end module et__jensen_haise