storm_drain_capture.F90

Go to the documentation of this file.

module storm_drain_capture
 
  use iso_c_binding
 
  use constants_and_conversions
  use data_catalog
  use data_catalog_entry
  use datetime, only                 : datetime_t
  use grid, only                     : grid_writearcgrid
  use logfiles, only                 : logs, log_all
  use exceptions, only               : warn, assert
  use parameters, only               : params
  use simulation_datetime, only      : sim_dt
  use fstring_list, only              : fstring_list_t
  use fstring, only                  : ascharacter
  implicit none
 
  private
 
  public :: storm_drain_capture_fraction
  public :: storm_drain_capture_initialize, storm_drain_capture_calculate
 
  type (data_catalog_entry_t), pointer :: pstorm_drain_capture_fraction
  real (c_float), allocatable     :: storm_drain_capture_fraction(:)
  real (c_float), allocatable     :: storm_drain_capture_fraction_table(:)
  type ( datetime_t )                  :: date_of_last_retrieval
 
contains
 
  subroutine storm_drain_capture_initialize( is_cell_active, landuse_index )
 
    logical (c_bool), intent(in)     :: is_cell_active(:,:)
    integer (c_int), intent(in)      :: landuse_index(:)
 
    ! [ LOCALS ]
    integer (c_int)              :: number_of_landuse_codes
    integer (c_int), allocatable :: lu_codes(:)
    integer (c_int)              :: indx
    integer (c_int)              :: num_records
    logical                           :: are_lengths_unequal
    type (fstring_list_t)              :: string_list
    integer (c_int)              :: status
    character (len=256)               :: sbuf
 
    call string_list%append("LU_Code")
    call string_list%append("Landuse_Code")
    call string_list%append("Landuse_Lookup_Code")
 
    !> Determine how many UNIQUE landuse codes are present
    call params%get_parameters( slkeys=string_list, ivalues=lu_codes )
    number_of_landuse_codes = count( lu_codes >= 0 )
 
    call string_list%clear()
    call string_list%append("Storm_drain_capture")
    call string_list%append("Storm_drain_capture_fraction")
 
    allocate( storm_drain_capture_fraction( count( is_cell_active ) ), stat=status )
    call assert( status==0, "Problem allocating STORM_DRAIN_CAPTURE_FRACTION", &
      __file__, __line__ )
 
    ! set default value for STORM_DRAIN_CAPTURE_FRACTION
    storm_drain_capture_fraction = 0.0_c_float
 
    !> Determine how many storm_drain_capture codes are present
    call params%get_parameters( slkeys=string_list, fvalues=storm_drain_capture_fraction_table )
 
    call string_list%clear()
 
    ! attempt to locate storm drain capture information in gridded format
    pstorm_drain_capture_fraction => dat%find( "STORM_DRAIN_CAPTURE_FRACTION" )
 
   if ( associated( pstorm_drain_capture_fraction ) ) then
 
     ! nothing to do...
 
   elseif ( storm_drain_capture_fraction_table(1) > ftinyval ) then
 
     !> check: number of STORM_DRAIN_CAPTURE_FRACTION_TABLE values == number of landuse codes?
     num_records = ubound(storm_drain_capture_fraction_table, 1)
     are_lengths_unequal = ( num_records /= number_of_landuse_codes )
 
     if ( are_lengths_unequal ) then
 
       sbuf = "The number of values specifying storm drain capture"                         &
         //" fraction ("                                                                    &
         //ascharacter( num_records )//") does not match the number of landuse values ("    &
         //ascharacter( number_of_landuse_codes )//"). Setting default storm drain"         &
         //" capture to 0.0 (ZERO)."
 
       call warn( smessage=trim(sbuf),                                                      &
                 smodule=__file__,                                                      &
                 iline=__line__,                                                           &
                 lfatal=.false._c_bool,                                                    &
                 iloglevel=log_all )
 
       storm_drain_capture_fraction = 0.0_c_float
 
     else
 
       do indx=lbound( landuse_index, 1 ), ubound( landuse_index, 1 )
         storm_drain_capture_fraction( indx ) = storm_drain_capture_fraction_table( landuse_index( indx ) )
       enddo
 
      endif
 
      deallocate( storm_drain_capture_fraction_table, stat=status )
      call assert( status==0, "Problem allocating STORM_DRAIN_CAPTURE_FRACTION_TABLE", &
        __file__, __line__ )
 
    endif
 
  end subroutine storm_drain_capture_initialize
 
!--------------------------------------------------------------------------------------------------
 
  subroutine storm_drain_capture_calculate( capture_fraction, indx, is_cell_active )
 
    real (c_float), intent(inout)     :: capture_fraction
    integer (c_int), intent(in)       :: indx
    logical (c_bool), intent(in)      :: is_cell_active(:,:)
 
    ! attempt to update values from gridded source, if active
    if ( .not. date_of_last_retrieval == sim_dt%curr ) then
 
      associate( dt => sim_dt%curr )
 
        if ( associated( pstorm_drain_capture_fraction ) ) then
          call pstorm_drain_capture_fraction%getvalues( dt )
          if ( pstorm_drain_capture_fraction%lGridHasChanged ) then
            storm_drain_capture_fraction = pack( pstorm_drain_capture_fraction%pGrdBase%rData, is_cell_active )
            call grid_writearcgrid("Storm_drain_capture_fraction__as_read_into_SWB.asc", &
              pstorm_drain_capture_fraction%pGrdBase )
          endif
        endif
 
        date_of_last_retrieval = sim_dt%curr
 
      end associate
 
    endif
 
    if ( allocated( storm_drain_capture_fraction ) )                           &
      capture_fraction = storm_drain_capture_fraction( indx )
 
  end subroutine storm_drain_capture_calculate
 
end module storm_drain_capture