fog__monthly_grid.F90

Go to the documentation of this file.

!> @file
!! Contains the module \ref fog__monthly_grid.
 
!>
!!  Module \ref fog__monthly_grid
!!  provides support for estimating fog drip given a gridded map
!!  of FOG_RATIO and FOG_CAPTURE_EFFICIENCY.
 
module fog__monthly_grid
 
  use iso_c_binding
  use constants_and_conversions
  use data_catalog
  use data_catalog_entry
  use dictionary
  use exceptions
  use file_operations
  use logfiles, only            : logs, log_all
  use parameters, only          : params
  use simulation_datetime
  use fstring
  use fstring_list
 
  implicit none
 
  private
 
  public :: fog_monthly_grid_initialize, fog_monthly_grid_calculate, pfog_ratio
 
  type (data_catalog_entry_t), pointer :: pfog_ratio
  real (c_float), allocatable     :: ffog_catch_efficiency(:)
 
contains
 
  !> Initialize the fog drip algorithm.
  !!
  !! Read in a fog ratio grid.
  !! Open a NetCDF output file to hold fog variable output.
  !!
  !! @param[in] lActive 2-D array of active cells within the model domain.
  subroutine fog_monthly_grid_initialize( lActive )
 
    logical (c_bool), intent(in)     :: lactive(:,:)
 
    ! [ LOCALS ]
    type (fstring_list_t)           :: slstring
    integer (c_int), allocatable    :: ilandusecodes(:)
    integer (c_int)                 :: inumberoflanduses
    logical (c_bool)                :: larelengthsequal
 
    ! locate the data structure associated with the gridded fog ratio entries
    pfog_ratio => dat%find("FOG_RATIO")
    if ( .not. associated(pfog_ratio) ) &
        call die("A FOG_RATIO grid must be supplied in order to make use of this option.", __file__, __line__)
 
    !> Determine how many landuse codes are present
    call slstring%append("LU_Code")
    call slstring%append("Landuse_Code")
 
    call params%get_parameters( slkeys=slstring, ivalues=ilandusecodes )
    inumberoflanduses = count( ilandusecodes > 0 )
 
    call slstring%clear()
 
    call slstring%append("Fog_catch_eff")
    call slstring%append("Fog_catch_efficiency")
 
    call params%get_parameters( slkeys=slstring , fvalues=ffog_catch_efficiency )
 
    if ( ffog_catch_efficiency(1) <= ftinyval )  &
      call warn( "Failed to find a data column containing fog catch efficiency values.", lfatal=true, &
        iloglevel=log_all )
 
    larelengthsequal = ( ( ubound(ffog_catch_efficiency,1) == ubound(ilandusecodes,1) )  )
 
    if ( .not. larelengthsequal )     &
      call warn( smessage="The number of landuses does not match the number of fog catch efficiency values.",   &
        smodule=__file__, iline=__line__, lfatal=.true._c_bool )
 
  end subroutine fog_monthly_grid_initialize
 
!--------------------------------------------------------------------------------------------------
 
  subroutine fog_monthly_grid_calculate( fRainfall, fFog, iLanduse_Index, lActive, nodata_fill_value )
 
    real (c_float), intent(in)        :: frainfall(:)
    real (c_float), intent(inout)     :: ffog(:)
    integer (c_int), intent(in)       :: ilanduse_index(:)
    logical (c_bool), intent(in)      :: lactive(:,:)
    real (c_float), intent(in)        :: nodata_fill_value(:,:)
 
    ! [ LOCALS ]
 
    associate( dt => sim_dt%curr )
 
      if ( .not. associated(pfog_ratio) ) &
        call die("INTERNAL PROGRAMMING ERROR: attempted use of NULL pointer", __file__, __line__)
 
      if ( .not. allocated(pfog_ratio%pGrdBase%rData) ) &
        call die("INTERNAL PROGRAMMING ERROR: attempted use of unallocated variable", __file__, __line__)
 
      call pfog_ratio%getvalues( dt )
 
      ffog = frainfall * pack( pfog_ratio%pGrdBase%rData, lactive )   &
                       * ffog_catch_efficiency( ilanduse_index )
 
    end associate
 
  end subroutine fog_monthly_grid_calculate
 
end module fog__monthly_grid