main.F90

Go to the documentation of this file.

!> @file
!>  Main program which references all other modules; execution begins here.
 
 
!>  Main program which references all other modules; execution begins here.
!>
!> Accepts command-line arguments and makes a single call
!> to the control_setModelOptions routine in module \ref control.
program main
 
  use iso_c_binding, only             : c_short, c_int, c_float, c_double, c_bool, c_long
  use constants_and_conversions, only : os_native_path_delimiter, random_start, asint
  use disclaimers, only               : log_provisional_disclaimer,                          &
                                        write_provisional_disclaimer
  use logfiles, only                  : logs, log_debug
  use model_initialize, only          : initialize_all, read_control_file
  use model_domain, only              : model
  use model_iterate, only             : iterate_over_simulation_days
 
  use model_iterate_multiple_simulations, only  : iterate_over_multiple_simulation_days
 
  use fstring, only                   : operator(.containssimilar.),            &
                                          ascharacter, right
  use version_control, only           : swb_version, git_commit_hash_string,    &
                                        git_branch_string, compile_date,        &
                                        compile_time, system_name
  use fstring_list, only              : fstring_list_t
  use timer, only                     : timer_t
  use iso_fortran_env
 
  implicit none
 
  type (fstring_list_t)           :: slcontrolfiles
 
  character (len=256)            :: sbuf
  character (len=256)            :: soutputprefixname
  character (len=256)            :: soutputdirectoryname
  character (len=256)            :: slogfiledirectoryname
  character (len=256)            :: sdatadirectoryname
  character (len=256)            :: slookuptabledirectoryname
  character (len=256)            :: sweatherdatadirectoryname
  integer (c_int)                :: inumargs
  character (len=1024)           :: scompileroptions
  character (len=256)            :: scompilerversion
  character (len=:), allocatable :: scompilername
  character (len=256)            :: sversionstring
  character (len=256)            :: scompilationdatestring
  character (len=256)            :: scompilationsystemstring
  character (len=256)            :: sexecutabledescription
  character (len=256)            :: sgithashstring
  integer (c_int)                :: icount
  integer (c_int)                :: iindex
  integer (c_int)                :: ilen
  integer (c_int)                :: number_of_simulations
 
  type (timer_t)                 :: runtimer
 
  soutputprefixname         = ""
  soutputdirectoryname      = ""
  sdatadirectoryname        = ""
  slogfiledirectoryname     = ""
  slookuptabledirectoryname = ""
  sweatherdatadirectoryname = ""
  number_of_simulations = 1
 
  call runtimer%start()
 
  inumargs = command_argument_count()
 
  sversionstring = trim( swb_version )
  scompilationdatestring   = trim(compile_date)//" "//trim(compile_time)
  scompilationsystemstring = trim(system_name)
  scompileroptions = compiler_options()
  scompilerversion = compiler_version()
  sexecutabledescription = "USGS Soil-Water-Balance Code version "//trim( sversionstring )
 
  if ( system_name == "Windows" ) then
    os_native_path_delimiter = "\"
  else
    os_native_path_delimiter = "/"
  endif
 
  sgithashstring = trim( adjustl(git_branch_string ) )//", "//trim( git_commit_hash_string )
 
#ifdef __GFORTRAN__
  scompilername = "gfortran" // trim(scompilerversion)
#endif
 
#ifdef __INTEL_COMPILER
  ! populate with empty string, since for Intel the COMPILER_VERSION string contains
  ! the compiler name already
  scompilername = "Intel Fortran,"//right(string=scompilerversion, substring=",")
  scompilerversion = ""
!  write(UNIT=*,FMT="(a,/)") "compiler build date:"//TRIM(asCharacter(__INTEL_COMPILER_BUILD_DATE))
#endif
 
  icount = max( len_trim( sversionstring ), len_trim( sgithashstring ) )
  icount = max( icount, len_trim( scompilationsystemstring) )
  icount = max( icount, len_trim( scompilername) + len_trim( scompilerversion ) )
  icount = icount + 24
  icount = max( icount, len_trim( sexecutabledescription ) )
 
  write(unit=*, fmt="(/,a)") repeat("-",icount + 4)
  write(unit=*,fmt="(2x,a,/)") trim(sexecutabledescription)
  write(unit=*,fmt="(a24,a)") "compiled on : ", trim( scompilationdatestring )
  write(unit=*,fmt="(a24,a)") "compiled with : ", trim( scompilername )
  write(unit=*,fmt="(a24,a)") "compiled for : ",trim( scompilationsystemstring )
  write(unit=*,fmt="(a24,a)") "git hash and branch : ", trim( sgithashstring )
  write(unit=*, fmt="(a,/)") repeat("-",icount + 4)
 
  if(inumargs == 0 ) then
 
  write(unit=*,fmt="(a)")       " Compiler options :  "
  write(unit=*,fmt="(a,/,a,/)") "==================== ", trim( scompileroptions )
 
    call write_provisional_disclaimer()
 
    write(unit=*,fmt="(//,a,/,/,6(a,/))")  "Usage: swb2 [ options ] control_file_name ",                   &
             "[ --output_prefix= ]     :: text to use as a prefix for output filenames",                   &
             "[ --output_dir= ]        :: directory to place output in (may be relative or absolute)",     &
             "[ --lookup_dir= ]        :: directory to search for lookup tables",                          &
             "[ --logfile_dir= ]       :: directory to write logfiles to",                                 &
             "[ --data_dir= ]          :: directory to search for input data grids",                       &
             "[ --weather_data_dir= ]  :: directory to search for weather data grids"
!               "[ --random_start= ]      :: advance random number generator to this position in the series", &
!               "[ --number_of_sims= ]    :: number of simulations to run when 'method of fragments' is used"
    stop
 
  end if
 
  do iindex=1, inumargs
 
    call get_command_argument( iindex, sbuf )
 
    if ( sbuf(1:13) .eq. "--output_dir=" ) then
 
      soutputdirectoryname = trim( sbuf(14:) )
      ilen = len_trim( soutputdirectoryname )
 
      ! if there is no trailing "/", append one so we can form (more) fully
      ! qualified filenames later
      if ( .not. soutputdirectoryname(ilen:ilen) .eq. os_native_path_delimiter )  &
        soutputdirectoryname = trim(soutputdirectoryname)//os_native_path_delimiter
 
    elseif( sbuf(1:15) .eq."--random_start=" ) then
 
      random_start = int( asint( sbuf(16:) ), c_long )
 
    elseif( sbuf(1:17) .eq."--number_of_sims=" ) then
 
      number_of_simulations = asint( sbuf(18:) )
 
    elseif ( sbuf(1:16) .eq. "--output_prefix=" ) then
 
      soutputprefixname = trim( sbuf(17:) )
      ilen = len_trim( soutputprefixname )
 
    elseif ( sbuf(1:11) .eq. "--data_dir=" ) then
 
      sdatadirectoryname = sbuf(12:)
      ilen = len_trim( sdatadirectoryname )
 
      ! if there is no trailing "/", append one so we can form (more) fully
      ! qualified filenames later
      if ( .not. sdatadirectoryname(ilen:ilen) .eq. os_native_path_delimiter )  &
        sdatadirectoryname = trim(sdatadirectoryname)//os_native_path_delimiter
 
    elseif ( sbuf(1:14) .eq. "--logfile_dir=" ) then
      slogfiledirectoryname = sbuf(15:)
      ilen = len_trim( slogfiledirectoryname )
 
      ! if there is no trailing "/", append one so we can form (more) fully
      ! qualified filenames later
      if ( .not. slogfiledirectoryname(ilen:ilen) .eq. os_native_path_delimiter )  &
      slogfiledirectoryname = trim(slogfiledirectoryname)//os_native_path_delimiter
 
    elseif ( sbuf(1:13) .eq. "--lookup_dir=" ) then
 
      slookuptabledirectoryname = sbuf(14:)
      ilen = len_trim( slookuptabledirectoryname )
 
      ! if there is no trailing "/", append one so we can form (more) fully
      ! qualified filenames later
      if ( .not. slookuptabledirectoryname(ilen:ilen) .eq. os_native_path_delimiter )  &
      slookuptabledirectoryname = trim(slookuptabledirectoryname)//os_native_path_delimiter
 
    elseif ( sbuf(1:19) .eq. "--lookup_table_dir=" ) then
 
      slookuptabledirectoryname = sbuf(20:)
      ilen = len_trim( slookuptabledirectoryname )
 
      ! if there is no trailing "/", append one so we can form (more) fully
      ! qualified filenames later
      if ( .not. slookuptabledirectoryname(ilen:ilen) .eq. os_native_path_delimiter )  &
      slookuptabledirectoryname = trim(slookuptabledirectoryname)//os_native_path_delimiter
 
    elseif ( sbuf(1:19) .eq. "--weather_data_dir=" ) then
 
      sweatherdatadirectoryname = sbuf(20:)
      ilen = len_trim( sweatherdatadirectoryname )
 
      ! if there is no trailing "/", append one so we can form (more) fully
      ! qualified filenames later
      if ( .not. sweatherdatadirectoryname(ilen:ilen) .eq. os_native_path_delimiter )  &
        sweatherdatadirectoryname = trim(sweatherdatadirectoryname)//os_native_path_delimiter
 
    else
 
      ! no match on the command-line argument flags; this must be a control file
      call slcontrolfiles%append( trim( sbuf ) )
 
    endif
 
  enddo
 
  ! open and initialize logfiles
 
  ! allow for modification of the location in which logfiles will be written
  if ( len_trim( slogfiledirectoryname ) /= 0 ) then
    call logs%set_output_directory( trim( slogfiledirectoryname ) )
  elseif ( len_trim( soutputdirectoryname ) /= 0 ) then
    call logs%set_output_directory( trim( soutputdirectoryname ) )
  endif  
 
  call logs%initialize( iloglevel = log_debug )
 
  call log_provisional_disclaimer()
 
  call logs%write( smessage='Grid data directory name set to:',lecho=.true._c_bool )
  call logs%write( smessage='"'//trim( sdatadirectoryname )//'"', itab=4,lecho=.true._c_bool )
  call logs%write( smessage='Lookup table directory name set to:',lecho=.true._c_bool )
  call logs%write( smessage='"'//trim( slookuptabledirectoryname )//'"', itab=4,lecho=.true._c_bool )
  call logs%write( smessage='Weather data directory (precip, tmin, tmax grids) name set to: ',lecho=.true._c_bool )
  call logs%write( '"'//trim( sweatherdatadirectoryname )//'"',itab=4,lecho=.true._c_bool )
 
  call logs%write( smessage='Output will be written to: ',lecho=.true._c_bool )
  call logs%write( '"'//trim( soutputdirectoryname )//'"',itab=4,lecho=.true._c_bool )
  call logs%write( smessage='Output file prefix set to:',lecho=.true._c_bool )
  call logs%write( smessage='"'//trim( soutputprefixname )//'"', itab=4, lecho=.true._c_bool )
 
  if (random_start >0)   &
    call logs%write(smessage="Pseudo-random numbers will be pulled from index number "   &
           //trim(ascharacter(random_start))//" in the generated series.",               &
           lecho=.true._c_bool )
 
  if ( number_of_simulations > 1)  &
 
    call logs%write(smessage="Running multiple simulations; assuming method of fragments "   &
         //"was selected as the precipitation method.",                                      &
         lecho=.true._c_bool )
 
  ! idea is that there may be multiple control files fed to SWB; all of the files
  ! will be munged and the entries added to the CF_DICT dictionary
  do iindex=1, slcontrolfiles%count
    ! read control file
    call read_control_file( slcontrolfiles%get( iindex ) )
  enddo
 
  call slcontrolfiles%clear()
 
  call initialize_all( soutputprefixname, soutputdirectoryname,                &
                       sdatadirectoryname, slookuptabledirectoryname,          &
                       sweatherdatadirectoryname )
 
  call runtimer%stop()
  call runtimer%calc_time_values("split")
  call logs%write(smessage="Time spent initializing simulation: "              &
     //trim( runtimer%get_pretty()), lecho=.true._c_bool,                      &
     ilinesbefore=1, ilinesafter=1 )
 
  call runtimer%start()
 
  if ( number_of_simulations > 1) then
 
    call iterate_over_multiple_simulation_days(model, number_of_simulations)
 
  else
 
    call iterate_over_simulation_days( model )
 
  endif
 
  call runtimer%stop()
  call runtimer%calc_time_values("split")
  call logs%write(smessage="Time spent running simulation: "                   &
     //trim( runtimer%get_pretty()), lecho=.true._c_bool,                      &
     ilinesbefore=1)
  call runtimer%calc_time_values("elapsed")
  call logs%write(smessage="Total runtime                : "                   &
    //trim( runtimer%get_pretty()), lecho=.true._c_bool,                       &
    ilinesafter=1 )
  call logs%close()
 
end program main